creazione colonna in columnview

[faustf]

Ciao a tutti nella versione di gambasa 3.16.3   come faccio ad aggiungere le colonne alla columnview ?  ce scritto di controllare nelle properties  ma non vedo  ne tasti +  ne  niente  che mi possa  indicare come aumentare il numero di colonne   qualcuno sa come  fare  >?

grazie a tutti

[Gianluigi]

Questo può servire?

Codice: [Seleziona]

Private hColumnView As ColumnView

Public Sub Form_Open()

  Dim hHBox As HBox
  Dim hButton As Button

  Me.Arrangement = Arrange.Vertical
  Me.Margin = True
  With hColumnView = New ColumnView(Me) As "ColumnView1"
    .Expand = True
    .Columns.count = 4
    '.Header = False
    .Columns[0].Alignment = Align.Center
    .Columns[0].Title = "Nome"
    .Columns[1].Title = "Amici 1"
    .Columns[2].Title = "Amici 2"
    .Columns[3].Title = "In competizione con"
    .add("first", "Pippo", Picture["icon:/16/clock"])
    hColumnView["first"][1] = "Pluto"
    hColumnView["first"][2] = "Paperino"
    hColumnView["first"][3] = "Gastone"
    .add("second", "Topolino", Picture["icon:/16/group"])
    hColumnView["second"][1] = "Minnie"
    hColumnView["second"][2] = "Basettoni"
    hColumnView["second"][3] = "Gamba di legno"
    .Columns[1].Width = -1
    .Columns[2].Width = -1
    .Columns[3].Width = -1
  End With
  With hHBox = New HBox(Me)
    .H = 35
  End With
  With hButton = New Button(hHBox) As "Button1"
    .W = 120
    .Text = "Add Column"
  End With

End

Public Sub ColumnView1_Click()

  Dim hGrid As GridView = hColumnView.Children[0]

  Print "Colonna "; hGrid.Column
  Print "Chiave "; Quote(hColumnView.Current.Key)
  Print "Valore "; Quote(hColumnView[hColumnView.Current.Key][hGrid.Column]); "\n"
  Print hColumnView.Item[hGrid.Column]

End

Public Sub Button1_Click()
  
  With hColumnView
    .Columns.Count = 5
    .Columns[4].Title = "Age"
    hColumnView["first"][4] = "31"
    hColumnView["second"][4] = "28"
  End With
  
End

[faustf]

grazie  ma quindi  mi confermi che nonlo si puo fare dalla interfaccia grafica ? giusto?

[faustf]

ma dove lo trovo Public Sub Form_Open() ??

[kicco]

ma dove lo trovo Public Sub Form_Open() ??

Form_Open è l'evento che viene sollevato quando lanci il programma e si apre il form.
Puoi scriverlo nel codice a mano, oppure con un doppio click sul form stesso, viene automaticamente prodotto il codice relativo

Public Sub Form_Open()
istruzioni che vuoi
end

dentro il quale scrivi le istruzione che verranno eseguite, appunto, all'apertura del form
Spero di essere stato abbastanza chiaro! 
 

[faustf]

mi sembri toppo avanti , ho provato a copiare incollare il codice dove dici ma non va mi da errore , mi sembra particolarmente difficile , ma non c-e-  la possibilita di aggiungere le  colonne da interfaccia grafica ?? va fatto solo cosi ??

[Gianluigi]

mi sembri toppo avanti , ho provato a copiare incollare il codice dove dici ma non va mi da errore , mi sembra particolarmente difficile , ma non c-e-  la possibilita di aggiungere le  colonne da interfaccia grafica ?? va fatto solo cosi ??

Gambas è un linguaggio di programmazione, pertanto occorre ... programmare, che vuol dire scrivere dei comandi.
Per vedere come funziona il codice che ti ho passato, devi aprire un nuovo progetto grafico in Gambas, nominarlo ad esempio TestColumnView, cliccare su Crea e in FMain tasto destro > Apri codice e copiare il codice e incollarlo.
Vedi immagine allegata

Se hai dei dubbi chiedi pure, buonanotte

[Gianluigi]

Anche se non è finito e in alcune parti è obsoleto ti consiglio di dare un'occhiata qui:
https://gambaswiki.org/wiki/tutorial
Se hai difficoltà con l'inglese o altre lingue e usi Firefox puoi installare dal menu di Firefox Strumenti > Estensioni il traduttore ImTranslator che ti permette di tradurre in italiano le frasi evidenziate.
Vedi immagine

Come già offerto, sono a disposizione per qualunque tuo dubbio.

[Gianluigi]

mi sembri toppo avanti , ho provato a copiare incollare il codice dove dici ma non va mi da errore

Quale errore, puoi riportarlo qui?

ma non c-e-  la possibilità di aggiungere le  colonne da interfaccia grafica ?? va fatto solo cosi ??

Come già detto Gambas è un linguaggio di programmazione e normalmente ci sono molti modi di ottenere un risultato e quasi sempre (come in questo caso) attraverso il codice

[cogier]

Forse questo semplice programma vi aiuterà.