[Risolto] Operare una sottrazione fra due vettori stringa.

[Gianluigi]

Ho il problema di sottrarre da un vettore stringa tutti i nomi presenti in un altro vettore.
Ho pensato di operare così:

Codice: [Seleziona]

Public Sub Main()

  Dim sAlls As String[] = ["Mickey Mouse", "Donald Duck", "Minnie", "Daisy Duck", "Goofy", "Pluto", "Scrooge McDuck", "Huey", "Dewey", "Louie", "Chip", "Dale"]
  Dim sDonald As String[] = ["Donald Duck", "Daisy Duck", "Scrooge McDuck", "Huey", "Dewey", "Louie"]
  Dim s As String
  Dim i As Integer

  Print "Devo sottrarre questi nomi:"
  For Each s In sDonald
    Print s
  Next
  Print
  Print "A questi altri:"
  For Each s In sAlls
    Print s
  Next
  sAlls.Insert(sDonald)
  sAlls.Sort()
  For i = sAlls.Max To 0 Step -1
    If i > 0 Then
      If sAlls[i] = sAlls[i - 1] Then
        sAlls.Delete(i)
        sAlls.Delete(i - 1)
        Dec i
      Endif
    Endif
  Next
  Print
  Print "Sono rimasti questi:"
  For Each s In sAlls
    Print s
  Next

End

Qualcuno ha un'idea migliore?

 

[Top Fuel]

Ci sto provando ma non mi riesce.

[vuott]

 

[vuott]

Si potrebbe proporre una cosa così:   

Codice: [Seleziona]

Public Sub Main()

  Dim sAlls As String[] = ["Mickey Mouse", "Donald Duck", "Minnie", "Daisy Duck", "Goofy", "Pluto", "Scrooge McDuck", "Huey", "Dewey", "Louie", "Chip", "Dale"]
  Dim sDonald As String[] = ["Donald Duck", "Daisy Duck", "Scrooge McDuck", "Huey", "Dewey", "Louie"]
  Dim s1, s2 As String

   s1 = sAlls.Join(Chr(0), Null)
  
   For Each s2 In sDonald
     s1 = Replace(s1, s2 & Chr(0), Null)
   Next

   sAlls = Split(s1, Chr(0))

   Print "Sono rimasti questi:\n"
   For Each s2 In sAlls
      Print s2
   Next

End

[Gianluigi]

Preferisco questa soluzione a quella da me proposta soprattutto perché agire sul contatore di For non mi convince e inoltre sfrutta in modo esemplare l'uso di Join (alter ego di Split).

Attenzione però, il piacere di vuott nell'iserire virtuosismi nel codice l'hanno spinto ad un uso non corretto di Replace, per evitare di usare il Null in Split inserisce un insidioso bug che possiamo verificare facendo finire i due vettori con la stessa voce.
Avremmo un confronto fra "voce" e "voce\x00" e così l'ultima non verrebbe eliminata.

Basta cambiare il codice così e credo che non dovrebbero esserci problemi:

Codice: [Seleziona]

Public Sub Main()

  Dim sAlls As String[] = ["Mickey Mouse", "Donald Duck", "Minnie", "Daisy Duck", "Goofy", "Pluto", "Scrooge McDuck", "Huey", "Dewey", "Louie", "Chip", "Dale"]
  Dim sDonald As String[] = ["Donald Duck", "Daisy Duck", "Scrooge McDuck", "Huey", "Dewey", "Louie", "Dale"]
  Dim s1, s2 As String

   s1 = sAlls.Join(Chr(0), Null)
  
   For Each s2 In sDonald
     s1 = Replace(s1, s2, Chr(0))
   Next
   
   sAlls = Split(s1, Chr(0), Null, True)

   Print "Sono rimasti questi:\n"
   For Each s2 In sAlls
      Print s2
   Next

End

 

[vuott]

Al problema rilevato si può ovviare anche modificando questa linea:

Codice: [Seleziona]

s1 = sAlls.Join(Chr(0), Null)

come segue:
s1 = sAlls.Join(Chr(0), Null) & Chr(0)


Ad ogni modo la tua rettifica è perfetta e, a mio avviso, preferibile.

[Gianluigi]

 
Houston, we've had a problem,

se noi riceviamo i dati da una cartella che contiene file nascosti che hanno lo stesso nome dei file visibili il codice non funziona, vedi codice:

Codice: [Seleziona]

Public Sub Main()

  Dim sAlls As String[] = ["Mickey Mouse", ".Mickey Mouse", "Donald Duck", ".Donald Duck", "Minnie", "Daisy Duck", "Goofy", ".Goofy", "Pluto", "Scrooge McDuck", "Huey", ".Huey", "Dewey", ".Dewey", "Louie", "Chip", "Dale"]
  Dim sDonald As String[] = ["Donald Duck", "Daisy Duck", "Scrooge McDuck", "Huey", "Dewey", "Louie"]
  Dim s1, s2 As String

   s1 = sAlls.Join("|", Null)
  
   For Each s2 In sDonald
     s1 = Replace(s1, s2, "|")
   Next
   
   sAlls = Split(s1, "|", Null, True)

   Print "Sono rimasti questi:\n"
   For Each s2 In sAlls
      Print s2
   Next

End

  

[vuott]

Houston, we've had a problem,

Puoi atterrare, allora, sul "Mare tranquillitatis" della Luna:

Codice: [Seleziona]

Public Sub Main()

  Dim sAlls As String[] = ["Mickey Mouse", ".Mickey Mouse", "Donald Duck", ".Donald Duck", "Minnie", "Daisy Duck", "Goofy", ".Goofy", "Pluto", "Scrooge McDuck", "Huey", ".Huey", "Dewey", ".Dewey", "Louie", "Chip", "Dale"]
  Dim sDonald As String[] = ["Donald Duck", "Daisy Duck", "Scrooge McDuck", "Huey", "Dewey", "Louie", "Dale"]
  Dim s1, s2 As String

   s1 = sAlls.Join(Chr(0), Null)

   For Each s2 In sDonald
     s1 = Replace(s1, s2, Chr(0))
   Next
   
   s1 = Replace(s1, ".\x00", Null)

   sAlls = Split(s1, Chr(0), Null, True)
   
   Print "Sono rimasti questi:\n"
   For Each s2 In sAlls
      Print s2
   Next

End

[Gianluigi]

Puoi atterrare, allora, sul "Mare tranquillitatis" della Luna:

 
Dovrebbero rimanere questi:

Codice: [Seleziona]

.Dewey
.Donald Duck
.Goofy
.Huey
.Mickey Mouse
Chip
Goofy
Mickey Mouse
Minnie
Pluto

e invece rimangono questi:

Codice: [Seleziona]

Mickey Mouse
.Mickey Mouse
Minnie
Goofy
.Goofy
Pluto
Chip

 

[vuott]

Ah, quindi quelli preceduti dal puntino non vanno elimnati, nonostante si riferiscano al medesimo personaggio. !?

[Gianluigi]

Ah, quindi quelli preceduti dal puntino non vanno elimnati, nonostante si riferiscano al medesimo personaggio. !?

Si e no vanno eliminati solo quelli del secondo vettore, trattandosi appunto di Operare una sottrazione fra due vettori stringa  

Mi spiego meglio: se nel secondo vettore ci fosse ad esempio ".Donald Duck" andrebbe eliminato anche lui malgrado il puntino, ora è più chiaro spero
 

[vuott]

Mi spiego meglio: se nel secondo vettore ci fosse ad esempio ".Donald Duck" andrebbe eliminato anche lui malgrado il puntino, ora è più chiaro spero

Uhmmm.... allora poniamo - a titolo esemplificativo - nel secondo vettore di tipo String i signori Donaldo Ducco e Uèi  preceduti entrambi  dal puntino:

Codice: [Seleziona]

Public Sub Main()

  Dim sAlls As String[] = ["Mickey Mouse", ".Mickey Mouse", "Donald Duck", ".Donald Duck", "Minnie", "Daisy Duck", "Goofy", ".Goofy", "Pluto", "Scrooge McDuck", "Huey", ".Huey", "Dewey", ".Dewey", "Louie", "Chip", "Dale"]
  Dim sDonald As String[] = ["Donald Duck", "Daisy Duck", ".Huey", "Scrooge McDuck", ".Donald Duck", "Huey", "Dewey", "Louie", "Dale"]
  Dim s As String
   
   For Each s In sDonald
     sAlls.Remove(sAlls.Find(s, gb.Binary, 0), 1)
   Next


   Print "Sono rimasti questi:\n"
   For Each s In sAlls
      Print s
   Next

End

Ovviamente questo brevissimo e semplicissimo codice può ben sostituire la mia precedente soluzione:
http://www.gambas-it.org/smf/index.php?topic=6191.msg43402#msg43402

[Gianluigi]

Moooolto bene, avevo visto questo suggerimento sulla ML fatto da Jussi credo ma non ne avevo ben capito la portata.
Molte grazie per avermelo fatto capire   

Oltretutto credo che l'uso di Find non dovrebbe creare la famosa 'quadraticità', o come caspita si dice, tanto paventata in tutti gli interventi sui vettori anche da parte di Minisini.
Credo che 0^2 si crei, ma non ne sono sicuro, quando si confrontano due voci dello stesso vettore tipo voce[n] = voce[n - 1], Find essendo interno a Gambas senz'altro non lo fa.
 

P.S: Chissà se qualche anima pia  che ben conosce il C vorrà indagare su come lavora Find?

[vuott]

...Find essendo interno a Gambas senz'altro non lo fa.

...perché osservi la "superficie", il grazioso volto di Gambas; bisognerebbe vedere il codice sorgente, scritto in C, del Metodo .Find( ), nativo di Gambas, per verificare come avvengono in quelle "profondità" le comparazioni.

[Gianluigi]

...Find essendo interno a Gambas senz'altro non lo fa.

...perché osservi la "superficie", il grazioso volto di Gambas; bisognerebbe vedere il codice sorgente, scritto in C, del Metodo .Find( ), nativo di Gambas, per verificare come avvengono in quelle "profondità" le comparazioni.

Qualcuno mi legge nel pensiero, aiuto 
Intendo; guarda l'orario del tuo post e della mia ultima modifica sul post precedente.