Differenze tra le versioni di "Uso della classe Settings"

Versione attuale delle 03:33, 11 set 2022

La classe Settings consente di salvare su un file di testo .conf valori relativi ad "impostazioni" dell'applicazione, e che pertanto esse potranno essere recuperate anche dopo la chiusura del programma. Per usufruire delle funzionalità della Classe "Settings" bisognerà attivare il Componente gb.settings.

I valori possono essere sia numerici che stringa, anche array.

Il nome del file .conf sarà di default identico a quello del programma di appartenenza, e sarà salvato di default nel percorso:

User.Home &/ ".config/gambas3" &/ Application.Name & ".conf"

Esempio pratico:

Public Sub Button1_Click()

' Vengono stabiliti i valori delle impostazioni da salvare nel file .conf:
 Settings["Window/geometry"] = [100, 100, 300, 300, 0]
 Settings["Window/Top"] = 100
 Settings["Window/Left"] = 1000
 Settings["Window/Height"] = 200
 Settings["Window/Width"] = 200
 Settings["Uno/due"] = "testo qualsiasi"
 
' Per salvare le impostazioni durante lo svolgimento del programma è necessario il metodo "Save":
 Settings.Save

' Di default le informazioni saranno salvate nel file .conf con percorso che qui possiamo verificare così:
 Print Settings.Path

End

Successivamente possono essere recuperate, per essere utilizzate, così:

Public Sub Button2_Click()
 
 Dim s As String
 Dim i As Integer
 Dim iArr As Integer[]
 
' Vengono recuperate le informazioni relative alle impostazioni già salvate in “nome_file .conf”:
 i = Settings["Window/Top"]
 s = Settings["Uno/due"]
 iArr = Settings["Window/geometry"]
   
 Print i, s
   
 For Each i In iArr
   Print i,
 Next
 
End

Esiste un modo più veloce per salvare le impostazioni della finestra:

 Public Sub Form_Open()
 
   Settings.Read(Me)
 
 End

 Public Sub Form_Close()
 
' Nota: alla chiusura del programma Settings salva di default.
   Settings.Write(Me)
 
 End