Versione delle 12:32, 10 set 2022

Un Puntatore di Puntatore è una variabile di tipo Puntatore che punta ad un'altra variabile di tipo Puntatore. E' pertanto una variabile che contiene l'indirizzo di memoria di una variabile che a sua volta contiene l'indirizzo di memoria di una variabile contenente un valore, un dato, oppure di un'area riservata di memoria.

Per "dereferenziare" ^{[Nota 1]} un Puntatore di Puntatore, esistono almeno due modalità:

• mediante le apposite funzioni di dereferenziazione posseduta dai tipi nativi di dati;
• mediante i Memory Stream.

Le funzioni di dereferenziazione sono quelle che derefenziano il Puntatore nel relativo tipo di dato, al quale esse si riferiscono.
Esse sono: Byte@()", "Bool@()", Short@()", "Single@()", "Int@()", "Long@()", "Float@()", "String@()", "Pointer@()".

Vediamo un esempio pratico, nel quale prima verrà generato mediante la funzione "VarPtr()" un Puntatore di Puntatore, e poi si percorrerà il cammino al contrario riottenendo il valore puntato da un Puntatore puntato a sua volta da un Puntataore, così come lo abbiamo realizzato, nella prima modalità con una delle suddette funzioni di dereferenziazione, nella seconda modalità con i Memory Stream. Ad ogni modo, in entrambe le modalità di dereferenziazione il processo avviene con due fasi:

• dereferenziazione del "Puntatore" di "Puntatore", ottenendo il primo "Puntatore" (ossia l'indirizzo di memoria della variabile contenente il dato iniziale). Se si intende utilizzare una specifica funzione di dereferenziazione in questa prima fase, va usata la funzione "Pointer@()".
• dereferenziazione del "Puntatore", ottenendo il valore contenuto dalla variabile contenente il dato di partenza.

Public Sub Main()

 Dim b, n As Byte
 Dim p, p2, ritP, sP As Pointer
 Dim st, st2 As Stream

' Valore iniziale, che alla fine della dereferenziazione si dovrà riottenere:
 b = 44
  
' Crea il primo "Puntatore", che punta all'indirizzo di memoria della varianbile "b":
 p = VarPtr(b)
   
' Crea il secondo "Puntatore", che punta all'indirizzo di memoria della varianbile "p":
 p2 = VarPtr(p)
   

' Ora, dereferenzia il "Puntatore" di "Puntatore" con la funzione "Pointer@()":
 ritP = Pointer@(p2)

' Quindi dereferenzia il "Puntatore" ottenuto, per ricavare il valore contenuto iniziale della variabile "b":
 Print Byte@(ritP)


' Ora, invece, mostra come dereferenziare il "Puntatore" di "Puntatore" con i "Memory Stream":
 st2 = Memory p2 For Read
 Read #st2, sP
' Quindi dereferenzia il "Puntatore" ottenuto, per ricavare il valore contenuto iniziale della variabile "b":
 st = Memory sP For Read
 Read #st, b
 Print b
       
 st.Close
 st2.Close

End

Note

[1] Ricordiamo che "Dereferenziare " significa accedere al valore della variabile puntata dal Puntatore.