Generare un'onda sinusoidale con il componente gb.openal

Utilizzando le risorse della Classe " Alc " del Componente gb.openal di Gambas, è possibile eseguire un'onda sinusoidale, i cui dati saranno realizzati mediante appsota formula matematica.

Vediamo un esempio pratico:

Private Const AMPIEZZA As Byte = 127
Private Const FREQUENZA As Short = 880
Private Const CAMPIONAMENTO As Integer = 44100
Private Const DURATA As Single = 4.0


Public Sub Main()
 
 Dim disp As AlcDevice
 Dim cont As AlcContext
 Dim src, buffer As Integer[]
 Dim err As Boolean
 Dim Formato_audio As Integer
 Dim dati As New Byte[]
   
' Configura il dispositivo audio con la Classe "Alc":
  disp = Alc.OpenDevice(Null)
  If IsNull(disp) Then Error.Raise("Impossibile configurare il dispositivo audio !")
  
' Configura il contesto audio con la Classe "Alc":
  cont = Alc.CreateContext(disp)
  If IsNull(cont) Then Error.Raise("Impossibile configurare il contesto audio !")
  
  err = cont.MakeCurrent()
  If err = False Then Error.Raise("Impossibile creare il contesto audio !")
  
  src = Al.GenSources(1)
  
' Configura il buffer audio:
  buffer = Al.GenBuffers(1)
  
  Onda(dati)
  
  Formato_audio = 4352
  
' I dati audio sono caricati nel buffer audio:
  Al.BufferData(buffer[0], Formato_audio, dati.Data, dati.Count, CAMPIONAMENTO)
 
' Connette il buffer audio al sorgente audio:
  Al.Sourcei(src[0], Al.BUFFER, buffer[0])
  
' Esegue il sorgente audio:
  Al.SourcePlay(src[0])
  
' Consente l'esecuzione per l'intera durata dell'onda sonora:
  Sleep DURATA
  
' Libera la memoria:
  Al.DeleteBuffers(buffer)
  Al.DeleteSources(src)
  Alc.DestroyContext(cont)
  Alc.CloseDevice(disp)
  
End


Private Function Onda(bb As Byte[])   ' Crea i dati dell'onda sinusoidale
 
 Dim i As Integer
  
  For i = 0 To (DURATA * 2 * CAMPIONAMENTO) - 1
    bb.Push(CByte(128 + AMPIEZZA * Sin(CFloat(i / CAMPIONAMENTO * FREQUENZA * (2 * Pi)))))
  Next
  
End