Estrarre una traccia di un CD audio convertendola in un file MP3 con la funzione 'gst parse launch()' di GStreamer

La funzione esterna "gst_parse_launch()" della libreria GStreamer consente di costruire e gestire in modo semplice una pipeline GStreamer. La riga della pipeline gestita dalla funzione esterna "gst_parse_launch()" è un insieme di elementi separati da punti esclamativi (!).
Le proprietà possono essere aggiunte agli elementi, sotto forma di: proprietà = valore.

Sarà necessario avere installata nel sistema e richiamare nell'applicazione Gambas la libreria condivisa: "libgstreamer-1.0.so.0.2407.0" .

Mostriamo un esempio pratico, nel quale verrà estratta e convertita in un file MP3 la quarta traccia di un CD audio:

Library "libgstreamer-1.0:0.2407.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean
 
' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *cur)
' Queries an element for the stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, cur As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()
 
  Dim audio As Pointer
  Dim pos, dur As Long
  Dim po, du As Date

  gst_init(0, 0)

  audio = gst_parse_launch("cdparanoiasrc track=4 ! queue ! audioconvert ! lamemp3enc target=bitrate cbr=true bitrate=192 ! filesink location=/percorso/del/file.mp3", 0)   [nota 1]

' Avviamo l'estrazione e la contestuale conversione della traccia dal CD audio:
  gst_element_set_state(audio, GST_STATE_PLAYING)

  Repeat
    gst_element_query_position(audio, GST_FORMAT_TIME, VarPtr(pos))
    gst_element_query_duration(audio, GST_FORMAT_TIME, VarPtr(dur))
    po = Time(0, 0, 0, pos / 1000000)
    du = Time(0, 0, 0, dur / 1000000)
    Write "\rDurata: " & du & "      " & "Tempo trascorso: " & po
    Wait 0.01
  Until (pos > 0) And (CStr(po) >= CStr(du))

  gst_object_unref(audio)
  Print "\nEstrazione e conversione terminata."
  Quit
  
End

Note

[1] La riga di tipo stringa, posta nel 1° argomento della funzione esterna "gst_parse_launch()" può in alternativa anche essere la seguente:

"cdda://4 ! audioconvert ! lamemp3enc target=bitrate cbr=true bitrate=192 ! filesink location=/percorso/del/file.mp3"