Estrarre da un file WAV i dati audio grezzi mediante le sole risorse di Gambas

Per estrarre da un file WAV i soli dati audio grezzi unicamente mediante le funzioni di Gambas, è possibile utilizzare varie modalità. Ne mostriamo alcune:

Public Sub Main()

 Dim intero_file, dati_grezzi As String
 Dim n As Short
 
 intero_file = File.Load("/percorso/del/file.wav")

 n = InStr(intero_file, "data")
  
' Prendiamo i soli dati audio grezzi dal file, eliminando quelli che compongono il suo "header":
 dati_grezzi = Right(intero_file, Len(intero_file) - n - 7)
 
' ...oppure anche così:
' dati_grezzi = intero_file[(n + 7), intero_file.Len - (n + 7)]  [nota 1]
  
 File.Save("/tmp/grezzi", dati_grezzi)
 
End

Esempio in cui si utilizzano le funzioni dei vettori di tipo Byte[]:

Public Sub Main()

 Dim fileWAV As String
 Dim d As Short
 Dim bb As Byte[]
 
 fileWAV = "/percorso/del/file.wav"

' Carica un file audio Wav:
 bb = Byte[].FromString(File.Load(fileWAV))
 
' Individua la posizione del primo valore della parola "data" nel file wav:
 d = InStr(File.Load(fileWAV), "data")
 
' Scrive il file contenente i soli dati audio grezzi del file Wav:
 File.Save("/tmp/grezzi", bb.ToString(d + 7, bb.Count))
 
End

Esempio in cui vengono caricati in un'apposita Struttura alcuni dati del file Wav: numero canali, frequenza di campionamento, risoluzione, block align (quest'ultimo sarà utile per ottenere la durata del brano audio). Tali dati verranno poi mostrati in console ed utilizzati alcuni per calcolare la durata di esecuzione del file Wav:

Public Struct INFOWAV
  fileWAV As String      ' Percorso del file wav
  canali As Short        ' Numero dei canali
  frequenza As Integer   ' Frequenza di campionamento
  byte_rate As Integer   ' Byte Rate per secondo (quantità di byte processati ogni secondo)
  bit As Short           ' Risoluzione di campionamento in bit
  dati As Byte[]         ' Dati grezzi del file wav
  durata As Float        ' Durata di esecuzione del file wav
End Struct


Public Sub Main()
 
 Dim datiwav As New INFOWAV
  
 datiwav.fileWav = "/percorso/del/file.wav"
  
 EstraeDatiAudio(datiwav)
  
' Mostra in console le informazioni ottenute:
 With datiwav
   Print "File wav caricato:             "; .fileWAV
   Print "Numero dei canali:             "; .canali
   Print "Frequenza di campionamento: hz "; .frequenza
   Print "Risoluzione:                   "; .bit; " bit"
   Print "Durata dell'esecuzione:        "; Str(Time(0, 0, 0, .durata * 1000))
 End With

End


Private Function EstraeDatiAudio(iw As INFOWAV)

 Dim fl As File
 Dim d As Short
 
' Carica il file audio Wav:
 fl = Open iw.fileWAV For Read

' Individua il numero del byte ove è posto il TAG wav "data":
 d = InStr(File.Load(iw.fileWAV), "data")

 iw.dati = New Byte[Lof(fl) - (d + 7)]
  
' Carica nel vettore di tipo Byte[] i soli dati audio grezzi, posti a cominciare dal 7° byte "offset" dopo il primo byte del TAG wav "data":
 Seek #fl, d + 7
 iw.dati.Read(fl, 0, Lof(fl) - (d + 7))

' Legge il numero dei canali al byte d'indice (offset) 22:
 Seek #fl, 22
 iw.canali = Read #fl As Short

' Legge la frequenza di campionamento dei dati audio al byte d'indice (offset) 24:
 iw.frequenza = Read #fl As Integer

' Legge il valore del "Byte Rate" al byte d'indice (offset) 28:
 iw.byte_rate = Read #fl As Integer

' Legge la risoluzione bit del campionamento al byte d'indice (offset) 34:
 Seek #fl, 34 
 iw.bit = Read #fl As Short

' Calcola la durata dell'esecuzione del file wav:  [Nota 2]
 iw.durata = iw.dati.Count / iw.byte_rate

 fl.Close

End

Note

[1] Vedi la seguente pagina: Accedere ai caratteri contenuti da una variabile di tipo stringa come se questa fosse una vettore

[2] Vedi la seguente pagina: Calcolare la durata di un file audio WAV