Visualizza wikitesto di Estrarre e salvare singole immagini durante l'esecuzione di un file video mediante il Componente gb.media

Per estrarre e salvare mediante il Componente ''gb.media'' singole immagini da un file video durante la sua esecuzione all'interno di un Oggetto ''DrawingArea'', si posono adottare almeno tre modalità. <SUP>&#091;[[#Note|nota 1]]&#093;</sup>


==Uso delle sole risorse del Componente ''gb.media''==
Usando le sole risorse del Componente ''gb.media'', per catturare singole immagini, si farà uso della sotto-proprietà ".Image" della Proprietà ".Video" della Classe ''MediaPlayer''.

Mostriamo un esempio pratico, nel quale si farà uso di una ''DrawingArea'', nella quale sarà mostrato il video:
 Private mp As MediaPlayer
 Private i As Integer
 
 
 Public Sub Form_Open()
 
  Dim da As DrawingArea
     
 <FONT Color=gray>' ''Crea una "DrawingArea" come oggetto GUI da usare per l'uscita video:''</font>
  With da = New DrawingArea(Me)
    .X = 10
    .Y = 10
    .W = 300
    .H = 300
    .Background = Color.Black
  End With
   
  With mp = New MediaPlayer
    .URL = Media.URL("<FONT Color=darkgreen>''/percorso/del/file/video''</font>")
 <FONT Color=gray>' ''Imposta il controllo dell'uscita video da usare:''</font>
    .SetWindow(da)  ' <SUP>&#091;[[#Note|nota 2]]&#093;</sup>
  End With
   
 End
 
 
 Public Sub Button1_Click()
 
 <FONT Color=gray>' ''Esegue il file video:''</font>
  mp.Play()
   
  Repeat
 <FONT Color=gray>' ''Una brevissima pausa consente di mostrare e di agire sugli eventuali oggetti posti sul Form:''</font>
    Wait 0.01
    Label1.Text = "\rDurata del video: " & CStr(Time(0, 0, 0, mp.Duration * 1000)) &
                  "   -   Tempo trascorso: " & CStr(Time(0, 0, 0, mp.Position * 1000))
  Until mp.Position >= mp.Duration
   
 End
 
 
 Public Sub Button2_Click()
  
  mp.Stop
  mp.Close
   
 End
 
 
 Public Sub ToggleButton1_Click()
  
  If ToggleButton1.Value Then
    mp.Pause
  Else
    mp.Play
  Endif
   
 End
 
 
 Public Sub Button3_Click()
 
  Dim img As Image
  Dim s As String
   
  img = <FONT Color=red>mp.Video.Image</font>
  Inc i
  s = CStr(i)
  img.Save("/tmp/foto_" & s & ".png", 100)
   
  Write #File.out, "\rImmagine catturata: " & s
   
 End


====Con applicazione a ''riga di comando''====
Vediamo un paio di esempi simili al precedente però con un'applicazione a ''riga di comando''.
<BR>Nel primo esempio sarà possibile cattura un'immagine per volta scrivendo nello spazio della console il carattere "c" e successivamente premendo il tasto "Invio" della tastiera. Se si premerà solo e semplicemente il tasto "Invio", il programma verrà terminato.
 Private bo As Boolean
 Private mp As New MediaPlayer
 Private i As Integer
 
 
 Public Sub Main()
  
  mp.URL = Media.URL("<FONT Color=darkgreen>''/percorso/del/file/video''</font>")
  
  mp.Play
  
  Print "Durata del video: " & CStr(Time(0, 0, 0, mp.Duration * 1000))
  
  Repeat
    Wait 0.01
  Until (mp.Position >= mp.Duration) Or (bo = True)
  
  mp.Close
  Quit
  
 End
 
 
 Public Sub Application_Read()
 
  Dim img As Image
  Dim s As String
  
  Input s
  If s = "c" Then
    img = mp.Video.Image
    Inc i
    s = CStr(i)
    img.Save("/tmp/imm/foto_" & s & ".png", 100)
    Print "Immagine catturata: " & s
    Print
  Else
    bo = True
  Endif
  
 End
In quest'altro esempio la cattura sarà continua sino al termine del video:
 Private mp As New MediaPlayer
 Private i As Integer
 
 
 Public Sub Main()
  
  mp.URL = Media.URL("<FONT Color=darkgreen>''/percorso/del/file/video''</font>")
  
  mp.Play
  
  Print "Durata del video: " & CStr(Time(0, 0, 0, mp.Duration * 1000))
  
  Repeat
    Wait 0.001
  Until (mp.Position >= mp.Duration)
  
  mp.Close
  Quit
  
 End
 
 
 Public Sub Application_Read()
  
  Dim img As Image
  
  img = mp.Video.Image
  Inc i
  s = CStr(i)
  img.Save("/tmp/imm/foto_" & s & ".png", 100)
  Print "Immagine catturata: " & s
  
 End


==Uso della Classe ''DesktopWindow''==
Si potrà fare uso anche del Metodo ".GetScreenshot()" della Classe ''DesktopWindow''.
BR>Bisognerà attivare anche i Componenti ''gb.desktop'' e ''gb.desktop.x11''.

Mostriamo un esempio pratico, nel quale cliccando su ''Button1'' viene avviato il video. Quando si desidera catturare un'immagine dal video, si deve premere "Button2". Per terminare il programma e creare i file immagine, premere "Button3". I file immagine saranno salvati nel percorso "/tmp/immago".
 Private mp As MediaPlayer
 Private da As DrawingArea
 Private pc As New Picture[]
  
 
 Public Sub Form_Open()
  
 <FONT Color=gray>' ''Crea una "DrawingArea" come oggetto GUI da usare per l'uscita video:''</font>
  With da = New DrawingArea(Me)
    .X = 10
    .Y = 10
    .W = 480
    .H = 320
    .Background = Color.Black
  End With
  
  With mp = New MediaPlayer
    .URL = Media.URL("<FONT Color=darkgreen>''/percorso/del/file/video''</font>")
 <FONT Color=gray>' ''Imposta il controllo dell'uscita video da usare:''</font>
    .SetWindow(da)
  End With
  
 End
 
 
 Public Sub Button1_Click()
  
 <FONT Color=gray>' ''Avvia l'esecuzione del video:''</font>
  mp.Play()
   
 End
 
 
 Public Sub Button2_Click()
  
  Dim dw As DesktopWindow
   
  dw = New DesktopWindow(da.Handle)
   
 <FONT Color=gray>' ''Cattura una schermata del contenuto video mostrato in quel momento dalla "DrawingArea":''</font>
  pc.Push(dw.GetScreenshot(True))
   
 End
 
 
 Public Sub Button3_Click()   
 
  Dim i As Integer
  Dim drc, s As String
  
 <FONT Color=gray>' ''Arresta l'esecuzione del file video nella "DrawingArea":''</font>
  mp.Stop()
  
  drc = "/tmp/immago"
   
  If Not Exist(drc) Then
    Mkdir drc
  Else
    For Each s In Dir(drc, "picture_*", gb.file)
      Kill drc &/ s
    Next
  Endif
   
 <FONT Color=gray>' ''Genera infine i vari file immagine di formato .png:''</font>
  For i = 0 To pc.Max
    pc[i].Save(drc &/ "picture_" & CStr(i) & ".png", 100)
  Next
   
 End


==Uso della Classe ''Desktop''==
Si potrà anche fare uso del Metodo ".Screenshot()" della Classe ''Desktop''. Anche in questo caso bisognerà attivare i Componenti ''gb.desktop'' e ''gb.desktop.x11''.
<BR>Facendo riferimento all'esempio di codice precedente, la sub-routine dell'evento "''Button2_Click( )''" dovrà essere modificata come segue:
 Public Sub Button2_Click()
   
 <FONT Color=gray>' ''Cattura una schermata del contenuto video mostrato in quel momento dalla "DrawingArea":''</font>
  pc.Push(Desktop.Screenshot(da.ScreenX, da.ScreenY, da.W, da.H))
   
 End



=Note=
[1] Vedere anche le seguenti pagine della wiki:
* [[Estrarre e salvare singole immagini da una ripresa video mediante WebCam effettuata con il Componente gb.media]]
* [[Catturare singole immagini da una ripresa video di una webcam mediante il Controllo MediaView del Componente gb.media.form]]

[2] Riguardo all'Oggetto grafico da usare con il Metodo ".SetWindow()" della Classe "MediaPlayer", B. Minisini ha chiarito che esso necessita di un controllo che avesse una vera finestra X11 (o ayland), altrimenti se userà il primo controllo genitore con una finestra reale, che di solito è quella di primo livello.