Versione attuale delle 16:32, 3 lug 2024

Per modificare le dimensioni di una immagine caricata e gestita mediante il Componente gb.cairo, bisognerà utilizzare il Metodo ".Scale()" della Classe statica Cairo.

Nell'esempio che segue si utilizzeranno due immagini, una delle quali potrà essere ridimensionata rispetto all'altra ruotando in avanti o indietro la rotellina del mouse.
In particolare ruotando anche semplicemente avanti la rotellina del mouse, si attiverà un processo di ingrandimento continuo dell'immagine. Se si ruoterà indietro la rotellina, tale processo di ingrandimento si arresterà. Analogo comportamento si avrà ruotando indietro la rotellina: si avvierà un processo di rimpicciolimento dell'immagine; ma se si ruoterà poi in avanti la rotellina, quel processo si arresterà; e così via.
L'immagine risultante delle due caricate sarà visualizzata da un Oggetto "ImageView". ^{[nota 1]}

Private iv As ImageView
Private md As Short
Private sc As Float = 1.0


Public Sub Form_Open()
 
 With iv = New ImageView(Me) As "ImV"
   .X = 0
   .Y = 0
   .W = Me.W
   .H = Me.H
 End With
 
 Immagine(0.0)
  
End


Public Sub ImV_MouseWheel()
 
 md += Mouse.Delta
 
 If Mouse.Delta == 1 Then
   Repeat
     If md > 1 Then md = 1
     Immagine(0.001)
     Wait 0.03
   Until md < 1
 Else
   Repeat
     If md < -1 Then md = -1
     Immagine(-0.001)
     Wait 0.03
   Until md > -1
 Endif
 
End


Private Procedure Immagine(vf As Float)
 
 Dim im1, im2 As Image
 
' Carica la prima immagine (quella che sarà ridimensionata) avente, ad esempio, sfondo bianco che viene reso trasparente:
 im1 = Image.Load("/percorso/della/prima/immagine").Erase(Color.White)
 
' Carica la seconda immagine, le cui dimensioni resteranno invariate:
 im2 = Image.Load("/percorso/della/seconda/immagine")
 
 sc += vf
 
 With Cairo
   .Begin(im2)
   .Scale(sc, sc)
   .Source = .ImagePattern(im1, 0, 0)
   .Paint
   iv.Image = .Device
   .End
 End With
 
 Me.Caption = Format(sc, "0.000")
  
End

Note

[1] Vedere anche: Caricare un Oggetto ''Image'' direttamente in una ''ImageView'' con gb.cairo