Versione attuale delle 08:01, 4 dic 2023

Possiamo accedere alle Porte Seriali ^{[nota 1]} aprendo e leggendo direttamentre i dati provenienti dai relativi file-device.

Poniamo l'esempio di avere una penna USB per la connessione ad Internet, e che alla sua connessione il sistema operativo abbia generato due relativi file-device: "/dev/ttyUSB0 " e "/dev/ttyUSB1 " ^{[nota 2]}.
Possiamo leggere i dati provenienti dalla porta mediante due modalità:

• direttamente dal relativo file-device, ad esempio, "/dev/ttyUSB1 ";
• mediante l'apposita classe "SerialPort".

Mediante lettura diretta dal corrispondente file-device

Per il seguente esempio è necessario attivare anche il componente "gb.desktop", ed aver installato il programma "x-term":

Private fl As File


Public Sub Button1_Click()

' Se il file non possiede i più ampi permessi...
 If Stat("/dev/ttyUSB1").Auth <> "rwsrwxrwx" Then
' ...allora modificheremo in quel senso i permessi del file:
   Desktop.RunAsRoot("chmod 4777 /dev/ttyUSB1")
' Restiamo in attesa fino a che i permessi non vengono modificati, come desiderato:
   Repeat
     Wait 0.01
   Until Stat("/dev/ttyUSB1").Auth = "rwsrwxrwx"
 Endif

' In alternativa all'algoritmo precedente, si potrà utilizzare il seguente codice per impostare il setUID e consentire l'apertura del file protetto:
 Exec ["gksu", "chmod 4777", "/dev/ttyUSB1"] Wait

' ...o ancor più facilmente:
 Shell "echo MIA_PASSWORD | sudo -S chmod 4777 '/dev/ttyUSB1'" Wait

' Apriamo il file-device aggiungendo la parola chiave "Watch":
 fl = Open "/dev/ttyUSB1" For Read Watch

End


Public Sub File_Read()

 Dim s As String

 While Not Eof(fl)
' Leggiamo i dati provenienti dal file-device...:
   Line Input #fl, s
' ...e li mostriamo in console:
   Print s
 Wend

End

Lettura mediante la Classe SerialPort

La lettura della Porta Seriale portà avvenire anche mediante l'uso della Classe "SerialPort" attivando il componente gb.net.

Private SerialPort1 As SerialPort


Public Sub Button1_Click()

 SerialPort1 = New SerialPort As "portaseriale"

' Facciamo in modo da poter inserire la password di root per impostare il setUID e consentire l'apertura del file protetto:
 Shell "echo 'MIA_PASSWORD' | sudo -S chmod 4777 '/dev/ttyUSB1'" Wait

 With SerialPort1
   .PortName = "/dev/ttyUSB1"
   .Speed = 19200
   .Parity = 0
   .DataBits = 8
   .StopBits = 1
   .FlowControl = 0
   .Open
 End With

End


Public Sub portaseriale_Read()

 Dim s As String

' Legge i dati dalla porta....
 Read #SerialPort1, s, Lof(SerialPort1)

' ...e li mostra in console:
 Print s

End


Public Sub Form_Close()

 If SerialPort1.Status = Net.Active Then SerialPort1.Close

End

Altri codici esemplificativi

Gli utenti iscritti al Forum www.gambas-it.org possono scaricare anche altri due programmi ben più complessi:

• https://www.gambas-it.org/smf/index.php?action=dlattach;topic=8863.0;attach=5570 ^{[nota 3]}
• https://www.gambas-it.org/smf/index.php?action=dlattach;topic=8863.0;attach=5575 ^{[nota 4]}

Note

[1] Vedere anche questa pagina: Approfondimento sull'accesso alle porte USB

[2] In tali altri casi il file-device creato può essere: "/dev/ttyACM0"

[3] Il codice è stato realizzato dall'utente "kicco "

[4] Il codice è stato realizzato dall'utente "astragalo ".

Approfondimenti in internet

• http://www.cmrr.umn.edu/~strupp/serial.html
• http://www.tldp.org/HOWTO/Serial-HOWTO.html