Versione delle 08:00, 7 gen 2024

E' possibile utilizzare due o anche più programmi Gambas contemporaneamente, che si passano valori attraverso lo "standard Output " e lo "standard Input " ^{[nota 1]}, mediante "Process".

Facciamo un esempio in cui abbiamo un programma principale e uno secondario.

Avremo il programma principale che avvia il programma secondario (che chiameremo: secondo.gambas) e lo gestisce con Process.
Il programma principale invia mediante Process un dato numerico al programma secondario.
Il programma secondario intercetta quindi con l'evento _Read() il dato passato dallo "Standard Input", lo mostra in una TextLabel e lo modifica sommandolo ad un altro valore. Dopo ciò esso invierà il dato, come modificato, al programma principale mediante lo "Standard Output".
Il programma principale intercetterà il dato, inviatogli dal programma secondario, mediante l'evento "_Read()" della Classe Process leggendolo dal flusso del processo rappresentato dalla variabile di tipo Process.

Private scnd As Process


Public Sub Button1_Click()

' Avviamo il programma secondario e lo gestiamo con "Process":
 scnd = Shell "/percorso/del/programma/secondo.gambas" For Read Write As "secondo"
 
' oppure:
 scnd = Exec ["/percorso/del/programma/secondo.gambas"] For Read Write As "secondo"

End


Public Sub Button2_Click()

' Inviamo al programma secondario il valore numerico:
 Write #scnd, 99 As Byte

End


' Se potrà essere letto almeno un byte dal processo "secondo", verrà sollevata questa subroutine:
Public Sub secondo_Read()

 Dim b As Byte

' Legge i dati scritti dal programma secondo:
 Read #scnd, b

' Qui mostriamo in console il dato intercettato:
 TextLabel1.Text = "Dato intercettato modificato = " & CStr(b)
 
End

Il programma secondario (chiamato: secondo.gambas) che intercetta attraverso lo "Standard Input" il dato inviatogli, e lo re-invia - come modificato - al programma principale attraverso lo "Standard Output", sarà questo:

Private flIn As File


Public Sub Form_Open()

' Apre lo standard Input per la lettura...
 flIn = Open "/dev/stdin" For Read Watch

End


Public Sub File_Read()

 Dim out As File
 Dim b As Byte

' Legge il dato passato dallo standard Input:
 Read #flIn, b

 flIn.Close

' Mostra nella propria TextLabel il dato intercettato:
 TextLabel1.Text = CStr(b)

' Effettua la modifica del dato intercettato:
 Inc b

' Apre lo standard Output per la Scrittura...
 out = Open "/dev/stdout" For Write

' ...e vi scrive il nuovo valore della variabile "b":
 Write #out, b As Byte

 out.Close

End

Al termine dell'intera procedura avremo nella TextLabel del programma secondario scritto il dato: 99, mentre nella TextLabel del programma principale scritto il dato come modificato: 100.

Note

[1] Quando un programma viene eseguito, il sistema operativo genera tre file chiamati rispettivamente: "standard input ", "standard output " e "standard error ".
Di norma lo "standard input " è riferito alla tastiera, mentre lo "standard output " e lo "standard error " sono riferiti allo schermo.
Ogni rapporto e riferimento ai file avviene attraverso un proprio Puntatore al file, chiamato "descrittore di file ". I descrittori di questi tre file sono rappresentati con i numeri: 0, 1 e 2:
0 = "standard input ": il programma legge i dati scritti/inviati dalla periferica.
1 = "standard output ": il programma scrive/invia dati alla periferica, la quale legge i dati inviati dal programma.
2 = "standard error ": il programma scrive/invia messaggi d'errore al video.
I dati introdotti in input con la tastiera vengono inseriti all'interno di un canale costituito da una sequenza continua di byte. Allo stesso modo i dati prodotti a video vengono inseriti all'interno di un altro canale. Tali canali vengono definiti standard input e standard output. Pertanto la tastiera e' il canale standard input ed il video e' il canale standard output. Qualsiasi comando quindi, accetta in input dei valori che legge dallo standard input (la tastiera) e produce dei risultati scrivendoli nello standard output (il video). Ma un comando può produrre anche dei messaggi di errore se per esempio vengono introdotti dei valori in input non validi. I messaggi di errore dei comandi vengono scritti in un terzo canale, lo standard error.
Come già visto, ogni canale standard e' identificabile da un numero: 0 per il canale standard input, 1 per il canale standard output e 2 per il canale standard error.