Differenze tra le versioni di "Visualizzare uno spettroscopio di GStreamer mediante la funzione 'gst parse launch()' durante l'esecuzione di un file audio"
Da Gambas-it.org - Wikipedia.
(Creata pagina con "La funzione esterna ''gst_parse_launch()'' della libreria ''GStreamer'' consente di costruire e gestire in modo semplice una pipeline ''GStreamer''. La riga della pipeline ges...") |
|||
| Riga 7: | Riga 7: | ||
Mostriamo un esempio pratico: | Mostriamo un esempio pratico: | ||
| + | Private audio As Pointer | ||
| + | |||
| + | |||
Library "libgstreamer-1.0" | Library "libgstreamer-1.0" | ||
| Riga 39: | Riga 42: | ||
'''Public''' Sub Main() | '''Public''' Sub Main() | ||
| − | Dim | + | Dim pos, dur As Long |
| + | Dim po, du As Date | ||
gst_init(0, 0) | gst_init(0, 0) | ||
Versione delle 08:01, 10 apr 2016
La funzione esterna gst_parse_launch() della libreria GStreamer consente di costruire e gestire in modo semplice una pipeline GStreamer. La riga della pipeline gestita dalla funzione esterna gst_parse_launch() è un insieme di elementi separati da punti esclamativi (!). Le proprietà possono essere aggiunte agli elementi, sotto forma di: proprietà = valore.
Sarà necessario avere installata nel sistema e richiamare nell'applicazione Gambas la libreria dinamica condivisa: "libgstreamer-1.0"
Usando i plugin "spectrascope" e "autoaudiosink" all'interno della riga della pipeline della funzione gst_parse_launch(), è possibile visualizzare uno spettroscopio attivo durante l'esecuzione di un file audio di formato wav, mp3 ed .ogg.
Mostriamo un esempio pratico:
Private audio As Pointer
Library "libgstreamer-1.0"
Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3
' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)
' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer
' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer
' gboolean gst_element_query_duration(GstElement * element, GstFormat format, gint64 * duration)
' Queries an element For the total stream duration In nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean
' gboolean gst_element_query_position(GstElement * element, GstFormat format, gint64 * cur)
' Queries an element For the stream position In nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, cur As Pointer) As Boolean
' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)
Public Sub Main()
Dim pos, dur As Long
Dim po, du As Date
gst_init(0, 0)
audio = gst_parse_launch("filesrc location=/percorso/del/file/audio ! decodebin ! tee name=t " &
"! queue ! audioconvert ! spectrascope ! video/x-raw, width=1000, height=500! videoconvert ! autovideosink " &
"! queue ! audioconvert! m. t. ! queue ! autoaudiosink", 0)
' Avviamo l'esecuzione del file audio:
gst_element_set_state(audio, GST_STATE_PLAYING)
While True
gst_element_query_position(audio, GST_FORMAT_TIME, VarPtr(pos))
gst_element_query_duration(audio, GST_FORMAT_TIME, VarPtr(dur))
po = Date(0, 0, 0, 0, 0, 0, pos / 1000000)
du = Date(0, 0, 0, 0, 0, 0, dur / 1000000)
If (pos > 0) And (CStr(po) >= CStr(du)) Then Break
Write #File.Out, "\rDurata: " & du & " " & "Tempo trascorso: " & po
Wend
Termina()
End
Public Sub Application_Read()
Dim s As String
Input #File.In, s
Select Case s
Case "p"
' Pone in pausa la riproduzione del file mediale:
gst_element_set_state(audio, GST_STATE_PAUSED)
Case "r"
' Riprende la riproduzione del file mediale:
gst_element_set_state(audio, GST_STATE_PLAYING)
Case "s"
' Arresta la riproduzione del file mediale:
gst_element_set_state(audio, GST_STATE_NULL)
Termina()
End Select
End
Private Procedure Termina()
gst_object_unref(audio)
Print "\nEsecuzione terminata."
Quit
End
