Versione delle 10:11, 25 dic 2021

Per conoscere la dimensione del Dispositivo a blocchi e delle sue partizioni, è possibile utilizzare alcune funzioni esterne e principalmente la funzione ioctl() dichiarata nel file header .../sys/ioctl.h .

Conoscere la dimensione in Blocchi (Settori)

Poiché il secondo parametro della predetta funzione esterna ioctl() richiede - nel caso di restituzione dlla dimensione in Blocchi (Settori) - un valore passato da dalla funzione _IO(0x12,96), definita con l'identificatore BLKGETSIZE, non invocabile da Gambas con Extern, saremo costretti ad utilizzare un'apposita libreria dinamica condivisa esterna, da noi creata, per ottenere il valore rappresentato dal predetto identificatore.

Sarà, altresì, necessario eliminare preliminarmente la protezione del file-device della partizione di cui si intende conoscere la dimensione.

Mostriamo un esempio pratico:

Library "libc:6"

Private Const O_RDONLY As Integer = 0

' int open(const char *__file, int __oflag, ...)
' Open FILE and return a new file descriptor for it.
Private Extern open_C(__file As String, oflag As Integer) As Integer Exec "open"

' int close(int _fd)
' Deallocates the file descriptor indicated by fildes.
Private Extern close_C(_fd As Integer) As Integer Exec "close"

' int ioctl (int __fd, unsigned long int __request, ...)
' Perform the I/O control operation specified by REQUEST on FD.
Private Extern ioctl(__fd As Integer, __request As Long, arg3 As Integer) As Integer


' unsigned int Blkgetsize(void)
' Individua il valore di 'BLKGETSIZE'.
Private Extern Blkgetsize() As Integer In "/tmp/io"


Public Sub Main()
 
 Dim i As Integer
 Dim fd, p As Pointer
 
' Crea la nostra apposita libreria .so:
  File.Save("/tmp/io.c", "#include <linux/fs.h>" &
            "\n\n" &
            "unsigned int Blkgetsize() {\n" &
            "return BLKGETSIZE;\n}")
  Shell "gcc -o /tmp/io.so /tmp/io.c -shared" Wait
' ''''''''''''''''''''''''''''''''''''''''''''
  
' Elimina la protezione al file-device prescelto.
' E' necessario inserire la propria password !
  Shell "echo mia-password | sudo -s chmod 4777 '/dev/sda'" Wait
 
  fd = open_C("/dev/sda", O_RDONLY)
  p = Alloc(8)
  i = ioctl(fd, Blkgetsize(), p)
  If i < 0 Then Error.Raise("Errore alla funzione 'ioctl()' !")
  
  Print "\n\nNumero blocchi: "; Long@(p) &
  " che corrispondono a "; Format(Long@(p) * 512.0 / (1024 ^ 3), "##.###"); " GByte"
     
  close_C(fd)
  
  Free(p)
  
End

Conoscere la dimensione in Byte

Per avere, invece, la dimensione in byte, si dovrà utilizzare l'identificatore "BLKGETSIZE64":

Library "libc:6"

Private Const O_RDONLY As Integer = 0

' int open(const char *__file, int __oflag, ...)
' Open FILE and return a new file descriptor for it.
Private Extern open_C(__file As String, oflag As Integer) As Integer Exec "open"

' int close(int _fd)
' Deallocates the file descriptor indicated by fildes.
Private Extern close_C(_fd As Integer) As Integer Exec "close"

' int ioctl (int __fd, unsigned long int __request, ...)
' Perform the I/O control operation specified by REQUEST on FD.
Private Extern ioctl(__fd As Integer, __request As Long, arg3 As Integer) As Integer


' unsigned int Blkgetsize64(void)
' Individua il valore di 'BLKGETSIZE64'.
Private Extern Blkgetsize64() As Integer In "/tmp/io"


Public Sub Main()
 
 Dim i As Integer
 Dim fd, p As Pointer
 
' Crea la nostra apposita libreria .so:
  File.Save("/tmp/io.c", "#include <linux/fs.h>" &
            "\n\n" &
            "unsigned int Blkgetsize64() {\n" &
            "return BLKGETSIZE64;\n}")
  Shell "gcc -o /tmp/io.so /tmp/io.c -shared" Wait
' ''''''''''''''''''''''''''''''''''''''''''''
  
' Elimina la protezione al file-device prescelto.
' E' necessario inserire la propria password !
  Shell "echo mia-password | sudo -S chmod 4777 '/dev/sda'" Wait
 
  fd = open_C("/dev/sda", O_RDONLY)
  p = Alloc(8)
  i = ioctl(fd, Blkgetsize64(), p)
  If i < 0 Then Error.Raise("Errore alla funzione 'ioctl()' !")
  
  Print "\n\nDimensione: "; Format(Long@(p) / 1e9, "##.###"); " GByte"
     
  close_C(fd)
  
  Free(p)
  
End

Riferimenti

• http://man7.org/linux/man-pages/man4/sd.4.html
• http://lxr.free-electrons.com/ident?i=BLKGETSIZE