Un file banco di suoni di formato sf2 è semplicemente una libreria di suoni per la riproduzione di dati Midi che si basa su tabelle di suoni campionati (wavetable).

Il file contiene, dunque, dati audio di suoni campionati che possono essere successivamente manipolati dal calcolatore per generare le restanti frequenze sonore appartenenti a quel timbro originario.

Il file .sf2 è costituito, fra l'altro, da diversi blocchi comprendenti specifiche informazioni di carattere generale sul file stesso. In particolare il blocco denominato "pdtaphdr" contiene i nomi degli strumenti musicali e le rispettive posizioni all'interno del banco di suoni come vengono visualizzati dagli appositi programmi di gestione del file soundfont .sf2 .

L'esempio seguente mostra un possibile codice, con il quale estrarre dal blocco del blocco pdtaphdr i nomi e le rispettive posizioni degli strumenti musicali presenti nel file sf2.

Per ottenere questo risultato, bisognerà;

individuare il blocco pdtaphdr;
estrarre la dimensione del blocco pdtaphdr, che è rappresentata in Little-Endian dai 4 byte immediatamente successivi all'identificativo pdtaphdr (la dimensione è la quantità di byte dal primo byte successivo ai predetti 4 byte della dimensione del blocco fino all'identificativo del blocco pdag);
estrarre mediante apposita Struttura i valori del blocco pdtaphdr, ed in partciolare: il nome di ciascuno strumento musicale, il Banco dei suoni di appartenenza e la rispettiva posizione all'interno del banco di suoni del file sf2, tenendo presente che immediatamente dopo i 4 byte della dimensione del blocco pdtaphdr, vi sono uno o più gruppi di 38 byte, contenenti i predetti elementi da estrarre.

Il seguente codice mostrerà secondo la sequenza degli strumenti musicali all'interno del blocco pdtaphdr del file sf2: il numero di banco dei suoni, il preset ed il nome di ciascuno strumento.

Public Struct sfPresetHeader
  achPresetName[20] As Byte
  wPreset As Short
  wBank As Short
  wPresetBagNdx As Short
  dwLibrary As Integer
  dwGenre As Integer
  dwMorphology As Integer
End Struct


Public Sub Main()
    
 Dim fl As File
 Dim sf2, s As String
 Dim bb As Byte[]
 Dim i, j, durata As Integer
 Dim pphh1 As SfPresetHeader[]
 Dim sfPH As SfPresetHeader
       
  sf2 = "/percorso/del/file.sf2"
   
  fl = Open sf2 For Read
  If IsNull(fl) Then Error.Raise("Impossibile caricare il file '" & sf2 & " ' !")
   
  With bb = New Byte[Lof(fl)]
    .Read(fl, 0, Lof(fl))
    s = .ToString(0, bb.Count)
    If IsNull(s) then Error.Raise("Il file caricato non contiene dati !")
  End With
  bb.Clear
     
' Individua la posizione del Blocco 'pdtaphdr':
  i = InStr(s, "pdtaphdr")
  If i = 0 Then Error.Raise("Impossibile trovare il TAG 'pdtaphdr' !")
   
' Individua la quantità di byte che compongono l'intero blocco 'pdtaphdr':
  Seek #fl, i + 7
  j = Read #fl As Integer
 
' Raccoglie ad ogni ciclo 38 byte contenenti i vari elementi dello strumento musicale rappresentati dai membri della "Struttura".
' In particolare serviranno in seguito i primi tre membri: nome dello strumento musicale, preset (sua posizione all'interno del Banco) e numero del Banco di appartenenza.
  pphh1 = New SfPresetHeader[]

  While Seek(fl) < j + i
   
    sfPH = New SfPresetHeader
   
    With sfPH
      .achPresetName.Read(fl, 0, 20)
      .wPreset = Read #fl As Short
      .wBank = Read #fl As Short
      .wPresetBagNdx = Read #fl As Short
      .dwLibrary = Read #fl As Integer
      .dwGenre = Read #fl As Integer
      .dwMorphology = Read #fl As Integer
    End With
    
    pphh1.Add(sfph)
    
  Wend
  
  fl.Close

' Elimina l'ultima variabile di tipo "Struttura", poiché contenente i dati terminale del blocco 'pdtaphdr' che sono non significativi:
  pphh1.Remove(pphh1.Max)


' Vengono scritti in console i suoni degli strumenti musicali, secondo la loro posizione all'interno del blocco 'pdtaphdr',
' ed in particolare: il Banco dei suoni, il preset ed il nome dello strumento musicale:
  Print "Strumenti compresi nel file banco: "; File.Name(sf2)
  Print "\nBanco   Preset     Nome strumento\n"
  
  For j = 0 To pphh1.Max
    With pphh1[j]
      Print .wBank; "        ";
      Print .wPreset; "         ";
      Print .achPresetName.ToString()
    End With
  Next

' Fornisce alcune informazioni generali sul blocco 'pdtaphdr' del file .sf2:
  Print "\n\nFile soundbank: "; sf2
  Print "Dimensione totale suoni campionati: "; i;; "byte"
  durata = (i * 8) \ 705600
  Print "Durata totale dei suoni campionati: "; Date(0, 0, 0, 0, 0, 0, durata * 1000)
  
End

Il seguente codice mostrerà gli strumenti musicali secondo il rispettivo ordine ascendente del numero di banco di appartenenza e del loro preset:

Public Struct sfPresetHeader
  achPresetName[20] As Byte
  wPreset As Short
  wBank As Short
  wPresetBagNdx As Short
  dwLibrary As Integer
  dwGenre As Integer
  dwMorphology As Integer
End Struct


Public Sub Main()
   
 Dim fl As File
 Dim sf2, s As String
 Dim bb, bc As Byte[]
 Dim i, j As Integer
 Dim pphh1, pphh2, pphh3 As SfPresetHeader[]
 Dim sfPH As SfPresetHeader
      
  sf2 = "/percorso/del/file.sf2"
  
  fl = Open sf2 For Read
  If IsNull(fl) Then Error.Raise("Impossibile caricare il file '" & sf2 & " ' !")
  
  With bb = New Byte[Lof(fl)]
    .Read(fl, 0, Lof(fl))
    s = .ToString(0, bb.Count)
    If IsNull(s) Then Error.Raise("Il file caricato non contiene dati !")
  End With
  
' Individua la posizione del Blocco 'pdtaphdr':
  i = InStr(s, "pdtaphdr")
  If i = 0 Then Error.Raise("Impossibile trovare il TAG 'pdtaphdr' !")
  
' Individua la quantità di byte che compongono l'intero blocco 'pdtaphdr':
  Seek #fl, i + 7
  j = Read #fl As Integer

' Raccoglie ad ogni ciclo 38 byte contenenti i vari elementi dello strumento musicale rappresentati dai membri della "Struttura".
' In particolare serviranno in seguito i primi tre membri: nome dello strumento musicale, preset (sua posizione all'interno del Banco) e numero del Banco di appartenenza.
  pphh1 = New SfPresetHeader[]

  While Seek(fl) < j + i
  
    sfPH = New SfPresetHeader
  
    With sfPH
      .achPresetName.Read(fl, 0, 20)
      .wPreset = Read #fl As Short
      .wBank = Read #fl As Short
      .wPresetBagNdx = Read #fl As Short
      .dwLibrary = Read #fl As Integer
      .dwGenre = Read #fl As Integer
      .dwMorphology = Read #fl As Integer
    End With
    
    pphh1.Add(sfph)
    
  Wend
 
  fl.Close

' Elimina l'ultima variabile di tipo "Struttura", poiché contenente i dati terminale del blocco 'pdtaphdr' che sono non significativi:
  pphh1.Remove(pphh1.Max)

' Individua i banchi di suoni presenti nel file sf2:
  bc = New Byte[]
  
  For j = 0 To pphh1.Max
    If bc.Find(pphh1[j].wBank) = -1 Then bc.Push(pphh1[j].wBank)
  Next
  
' Ordina in modo ascendente i numeri dei banchi dei suoni:
  bc.Sort(gb.Ascent)

  pphh3 = New SfPresetHeader[]

  For i = 0 To bc.Max
    pphh2 = New SfPresetHeader[128]
   
' Per ordinare in modo ascendente gli strumenti, si selezionano solo quelli appartenenti ad uno dei Banchi presenti nell vettore "bc".
' Quindi, per ordinarli in modo ascendente secondo il proprio "preset", si assegna ciascuna variabile di tipo "Struttura", contenuta nel vettore "pphh1",
'  all'elemento del vettore "pphh2" avente indice corrispondente al valore del membro "wPreset" della variabile vettoriale che si sta assegnando:
    For j = 0 To pphh1.Max
      If pphh1[j].wBank = bc[i] Then pphh2[pphh1[j].wPreset] = pphh1[j]
    Next

' Il vettore "pphh2", così riempito in modo ordinato ascendente, viene inserito nella variabile vettoriale "pph3" in coda all'ultimo elemento già presente:
    pphh3.Insert(pphh2)
    pphh2.Clear
   
  Next

' Vengono eliminati gli eventuali elementi nulli della variabile vettoriale "pphh3":
  i = pphh3.Count
  j = 0

  While j < i
    If IsNull(pphh3[j]) Then
      pphh3.Remove(j)
      Dec i
      Dec j
    Endif
    Inc j
  Wend

  Print "Strumenti compresi nel file banco: "; File.Name(sf2)
  Print "\nPreset   Banco     Nome strumento\n"
  
' Vengono scritti in console il preset ed i nomi degli strumenti musicali, nonché il Banco degli strumenti di appartenenza:
  For j = 0 To pphh3.Max
    If j > 0 Then
      If (pphh3[j].wBank <> pphh3[j - 1].wBank) Then Print "--------------------------------------------"
    Endif
     
    With pphh3[j]
      Print .wBank; "        ";
      Print .wPreset; "         ";
      Print .achPresetName.ToString()
    End With
  Next
  
End

Individuare i nomi e le rispettive posizioni degli strumenti musicali in un file sf2 con le sole risorse di Gambas

Riferimenti

Menu di navigazione

Strumenti personali

Namespace

Varianti

Visite

Altro

Ricerca

Menu principale

Utilità