Nascondere un valore in una Struttura

Sappiamo che è possibile leggere e scrivere all'interno dell'area di memoria occupata da una Struttura.

Possiamo nascondere un valore all'interno di detta area di memoria, scrivendovelo, in modo tale que esso resti invisibile ed illegibile alla normale modalità per leggere i valori contenuti dai membri della Struttura.

Per fare ciò utilizzeremo i byte dell'area di memoria non occupati dai membri a causa dell'allineamento dei membri.

Mostriamo un esempio commentato:

Public Struct STRUCTURA
  b As Byte
  i As Integer
End Struct


Public Sub Main()

 Dim r As STRUCTURA
 Dim p, p2 As Pointer
 Dim st As Stream
 
  With r = New STRUCTURA
    .b = 99
    .i = 9999
  End With
   
' Vediamo in console i valori contenuti dai membri della "Struttura":
  Print "Valori iniziali della Struttura:"
  With r
    Print .b
    Print .i
  End With
  
  
' Nascondiamo (scriviamo) un valore di tipo "Short" nella Struttura:
  p = Object.Address(r)
  st = Memory p For Write
' I valori dell'area di memoria della Struttura, istanziata con la parola chiave "New", cominciano dal 25° byte (indice 24).
' In questo caso il byte di indice 24, essendo occupato dal valore del primo membro (di tipo Byte) della Struttura, ci costringe a porre
' il valore da nascondere al byte di indice 25 o a quello di indice 26.
  Seek #st, 25
  Write #st, 11111 As Short
  st.Close
   
' Vediamo ora se l'operazione di "nascondimento" (ossia di scrittura all'interno dell'area di memoria della Struttura) del valore di tipo "Short"
' ha procurato un'alterazione ai danni dei valori contenuti dai due membri della Struttura medesima:
  Print "\nValori della Struttura successivamente al nascondimento del valore di tipo 'Short' nella Strututra:"
  With r
    Print .b
    Print .i
  End With
      
   
' Ora andiamo a trovare il valore "nascosto" all'interno della Struttura.
' Utilizziamo una variabile di tipo "Puntatore" diversa da quella precedentemente usata, al fine di mostrare che puntando all'indirizzo dell'area di memoria
' della "Struttura", è possibile ottenere qualunque valore - anche a livello di singoli byte - in essa contenuto: 
  p2 = Object.Address(r)
  p2 = p2 + 25
  Print "\x0A\x0AIl valore è:\n"
  Print Short@(p2)
  
End