Leggere e scrivere direttamente nell'area di memoria di una Struttura accedendovi con la classe Object

Per poter leggere e scrivere dati in una Struttura, oltre all'uso più semplice dei suoi membri, è possibile accedere direttamente all'area di memoria della Struttura mediante i seguenti Metodi della Classe Object:

• "Object.Data()", il quale ritorna un Puntatore all'indirizzo di memoria ove sono referenziati i dati contenuti dai membri della Struttura;
• "Object.Address()", che ritorna l'indirizzo di memoria dell'Oggetto Struttura.

Leggere e scrivere direttamente nell'area di memoria di una Struttura usando il Metodo "Object.Data()"

La lettura nell'area di memoria di una Struttura potrà avvenire attraverso le funzioni native di Gambas di dereferenziazione dei Puntatori oppure tramite la risorsa Memory Stream.

Leggere una Struttura mediante le funzioni specifiche di dereferenziazione dei Puntatori

E' possibile leggere i valori dei membri di una Struttura facendo riferimento alla relativa variabile di tipo Struttura mediante un Puntatore e derefenziandolo con le funzioni native specifiche di dereferenziazione.

Mostriamo un esempio pratico:

Public Struct STRUTTURA
  b As Byte
  c As Short
  i As Integer
End Struct


Public Sub Main()

 Dim st As New STRUTTURA
 
 With st
   .b = 111
   .c = 2222
   .i = 333333
 End With
 
' Dereferenzia il "Puntatore" mediante le funzioni native di Gambas di dereferenziazione, rispettando, laddove necessario, la regola dell'Allineamento dei dati all'interno della "Struttura":
 Print Byte@(Object.Data(st))
 Print Short@(Object.Data(st) + 2)
 Print Integer@(Object.Data(st) + 4)

End

Leggere i dati presenti nell'area di memoria di una Struttura mediante i Memory Stream

Mostriamo un esempio pratico:

Public Struct STRUTTURA
  b As Byte
  c As Short
  i As Integer
End Struct


Public Sub Main()

 Dim st As New STRUTTURA
 Dim p As Pointer
 Dim sm As Stream
 Dim b As Byte
 Dim c As Short
 Dim i As Short
 
 With st
   .b = 111
   .c = 2222
   .i = 333333
 End With

 p = Object.Data(st)
  
' Dereferenzia il "Puntatore" mediante la risorsa "Memory Stream", anche in questo caso rispettando, laddove necessario, la regola dell'Allineamento dei dati all'interno della "Struttura":
 st = Memory p For Read
 Read #sm, b As byte
' In questo caso rispetta la regola dell'Allineamento dei dati, avanzando di un byte":
 Seek #sm, 2
 Read #sm, c As Short
 Read #sm, i As Integer
 Free(sm)


' Effettua la verifica":
 Print b
 Print c
 Print i

End

Leggere e scrivere direttamente nell'area di memoria di una Struttura usando il Metodo "Object.Address()"

Anche nel caso di uso del Metodo "Object.Address()" è possibile leggere e scrivere direttamente all'interno dell'area di memoria di una Struttura attraverso le funzioni naive di Gambas di dereferenziazione dei Puntatori oppure tramite la risorsa Memory Stream.

Va ricordato che la lettura e la scrittura avverranno prendendo come punto di riferimento iniziale il 25° (indice 24) byte di quell'area di memoria - i dati prescelti. Ciò si spiega con il fatto che il Metodo "Object.Address()" restituisce l'indirizzo di un Oggetto Gambas (in tal caso una Struttura) in memoria, non l'indirizzo dei dati a cui fa riferimento.

Leggere una Struttura mediante le funzioni specifiche di dereferenziazione dei Puntatori

E' possibile leggere i valori dei membri di una Struttura facendo riferimento alla relativa variabile di tipo Struttura mediante un Puntatore e derefenziandolo con le funzioni specifiche di dereferenziazione.

In particolare, la procedura prevede dapprima l'assegnazione dell'indirizzo di memoria della variabile della Struttura ad una variabile di tipo Puntatore, e successivamente la dereferenziazione graduale di tale Puntatore, leggendo al suo interno rispettando i byte di memoria occupati da ciascun membro della Struttura ed eventualmente effettuando i necessari allineamenti dei membri.

Mostriamo un semplice esempio:

Public Struct STRUTTURA
  b As Byte
  c As Short
  i As Integer
End Struct


Public Sub Main()

 Dim st As New STRUTTURA
 Dim p As Pointer
 
 With st
   .b = 9
   .c = 999
   .i = 99999
 End With

' Assegnamo al "Puntatore" l'indirizzo di memoria della variabile della "Struttura":
 p = Object.Address(st)
   
' Per scorrere all'interno del "Puntatore" lo sommiamo di volta in volta con un valore adeguato ad individuare il tipo di membro della "Struttura".
' Avendo utilizzato la parola chiave "New" nella dichiarazione della variabile della "Struttura", i valori del primo membro inizia al 25° byte (num. 24 di indice) dell'area di memoria occupata dalla "Struttura".
' Procede in questo caso come segue:

' Avanza al byte dell'area di memoria della Struttura occupato dal membro di tipo "Byte"
 Print Byte@(p + 24)

' Rispetto al byte d'indice 24 si deve avanzare di un byte per il necessario "allineamento" del primo e del secondo membro della Struttura; altresì si deve avanzare di un altro byte per giungere al dato-byte iniziale dei 2 byte occupati dal membro di tipo "Short"
 Print Short@(p + (24 + 1 + 1))
' o anche: Print Short@(p + (24 + SizeOf(gb.Short)))

' Rispetto al byte d'indice 24 si deve avanzare di altri due byte per raggiungere il dato-byte iniziale dei 4 byte occupati dal membro di tipo "Integer"
 Print Int@(p + (24 + 1 + 1 + 2))
' o anche: Print Int@(p + (24 + SizeOf(gb.Integer)))

End

Leggere e scrivere nell'area di memoria di una Struttura mediante i Memory Stream

Come sappiamo, una Struttura in sostanza non è altro che un'area riservata di memoria suddivisa al suo interno per settori (membri) di dimensione fra loro non (necessariamente) omogenea.

Lo scopo, quindi, è assegnare tale area di memoria ad un Puntatore, e successivamente attraverso i Memory Stream andare a leggere e/o scrivere in tale area, ossia nella Struttura. Come è evidente, dunque, il processo di lettura e di scrittura all'interno dei membri della Struttura avverrà in modo diverso, atipico rispetto alla normale modalità di lettura/assegnazione di valori che avviene richiamando direttamente i membri della Struttura medesima.

Mostriamo dunque un esempio,pratico: ^{[nota 1]}

Public Struct STRUTTURA
  b As Byte
  s As Short
  i As Integer
End Struct


Public Sub Main()

  Dim stru As New STRUTTURA
  Dim p As Pointer
  Dim st As Stream
  Dim b, j As Byte

' Assegnamo dei valori ai membri della Struttura:
  With stru
    .b = &01
    .s = &1234
    .i = &12345678
  End With

' Otteniamo l'indirizzo di memoria della Struttura:
  p = Object.Address(stru)

' Otteniamo dal Puntatore uno "Stream" in lettura e scrittura:
  st = Memory p For Read Write

' Leggiamo i valori contenuti nell'area di memoria della Struttura, per la sua intera dimensione, alla quale aggiungiamo 24 byte, dato che - utilizzando la parola "New" nella dichiarazione dela variabile di tipo "Struttura" ed il Metodo "Object.Address()" per ottenerne l'indirizzo di memoria - il valore del primo membro è posizionato al 25° byte (indice 24) dello "stream":
  For j = 0 To 24 + Object.SizeOf(stru) - 1
    Read #st, b
    If j == 24 Then 
      Print "\e[31m"; j, Hex(b, 2)
    Else
      Print j, Hex(b, 2)
    Endif
  Next

' Modifichiamo un valore (in questo caso quello del secondo membro, quello di tipo "Short") all'interno della Struttura usando lo "stream" precedentemente creato:
  Seek #st, 26
  Write #st, &0987 As Short

  st.Close

' Verifichiamo la scrittura del dato, leggendo ora direttamente il membro di tipo "Short" della Struttura:
   Print "\n\e[0m"; Hex(stru.s, 4)

End

Altro esempio analogo:

Public Struct STRUTTURA
  b As Byte
  s As Short
  i As Integer
End Struct


Public Sub Main()

 Dim stru As New STRUTTURA
 Dim p As Pointer
 Dim st As Stream
 Dim b As Byte

' Assegnamo l'indirizzo di memoria della Struttura ad un puntatore:
 p = Object.Address(stru)
   
' Otteniamo dal Puntatore uno "Stream" in scrittura:
 st = Memory p For Write
 
' Scriviamo dei valori nell'area riservata di memoria a cominciare dal byte d'indice offset n. 24 nel rispetto della disposizione dei byte all'interno dell'analoga area di memoria rappresentata dalla "Struttura":
 Seek #st, 24
 Write #st, 111 As Byte
 Write #st, 0 As Byte
 Write #st, 2222 As Short
 Write #st, 333333 As Integer

 st.Close


' Verifichiamo i valori ora presenti nei tre membri della "Struttura":
 With stru
   Print .b
   Print .s
   Print .i
 End With
 
End

Note

[1] Vedere anche: Ottenere il puntatore di una variabile di tipo Struttura

Pagina in costruzione !