Convertire i formati immagine mediante il Componente gb.media

Utilizzando i plugin di GStreamer con le Classi MediaControl e MediaPipeline del Componente gb.media, è possibile effettuare diverse conversioni di file immagine da un formato ad un altro.

Mostriamo di seguito qualche esempio pratico.

Conversione immagine da un qualunque formato al formato BMP

Public Sub Main()

 Dim pl As New MediaPipeline
 Dim src, deb, vdc, enc, snk As MediaControl
 Dim appoggio As String
 Dim i As Integer

 appoggio = Temp

 src = New MediaControl(pl, "filesrc")
 src["location"] = "/percorso/del/file/immagine"
 deb = New MediaControl(pl, "decodebin")
 vdc = New MediaControl(pl, "videoconvert")
 enc = New MediaControl(pl, "avenc_bmp")
 snk = New MediaControl(pl, "filesink")
 snk["location"] = appoggio
  
' Colleghiamo fra loro all'interno della pipeline gli oggetti MediaControl impostati:
 src.LinkTo(deb)
 deb.LinkLaterTo(vdc)
 vdc.LinkTo(enc)
 enc.LinkTo(snk)
 
 pl.Play()
  
 Repeat 
   i = Stat(appoggio).Size
   Wait 0.7
 Until Stat(appoggio).Size == i

 Copy appoggio To "/tmp/immagine.bmp"

 pl.Close
  
End

Conversione immagine nel formato JPG

Riprendendo il codice precedente, bisognerà sostituire le seguenti righe di comando a quelle corrispondenti in quel codice:

......
enc = New MediaControl(pl, "jpegenc")
......
Repeat 
  Wait 0.01
Until Right(File.Load(appoggio), SizeOf(gb.Short)) = MkShort(&D9FF)

Copy appoggio To "/tmp/immagine.jpg"
......

Conversione immagine nel formato PNG

Riprendendo il primo codice, bisognerà sostituire le seguenti righe di comando a quelle corrispondenti in quel codice:

......
enc = New MediaControl(pl, "pngenc")
......
Repeat 
  Wait 0.01
Until Right(File.Load(appoggio), SizeOf(gb.Integer)) = MkInt(&826042AE)

Copy appoggio To "/tmp/immagine.png"
......

Conversione immagine nel formato TIFF

Riprendendo il primo codice, bisognerà sostituire le seguenti righe di comando a quelle corrispondenti in quel codice.
Ovviamente in tal caso il file originario, da convertire, sarà di formato diverso dal TIFF.

......
enc = New MediaControl(pl, "avenc_tiff")
......
Repeat 
  Wait 1
Until Stat(appoggio).Size > 0

Copy appoggio To "/tmp/immagine.tif"
......