Contenere valori di diverso tipo

Come è noto una variabile di tipo vettore (array) è un'area di memoria riservata nella quantità determinata da una molteplicità di variabili del medesimo tipo, ossia che occupano tutte una uguale quantità di memoria.

Per contenere, invece, insieme valori di tipo diverso ^{[nota 1]}, che occupano cioè porzioni di memoria non uguali fra loro, è possibile utilizzare: ^{[nota 2]}

• la variabile vettoriale di tipo Variant;
• la Struttura;
• l'allocazione di memoria con la funzione "Alloc()", alla quale farà riferimento una variabile di tipo Puntatore. Per ricavare dati da tale area allocata, sarà necessario usare i Memory-Stream in modalità lettura (For Read ). Per scrivere, invece, dati in tale area di memoria così allocata, l'istruzione Memory sarà impostata in scrittura (For Write);
• una Classe specifica appositamente creata;
• una variabile vettoriale di tipo Object. ^{[nota 2]}

Note

[1] Poniamo il caso di voler contenere insieme variabili dei seguenti tipi: una variabile di tipo Byte, una variabile di tipo Short, tre variabili di tipo Integer ed una variabile di tipo Long. I tipi di queste variabili non sono omogenei, nel senso che occupano ciascuno una quantità di memoria diversa. Infatti, come si sa, la variabile di tipo Byte occupa un solo byte di memoria; la variabile di tipo Short occupa due byte di memoria; la variabile di tipo Integer occupa quattro byte di memoria; la variabile di tipo Long occupa otto byte di memoria.

[2] L'uso di un vettore (array) non è adatto per contenere insieme variabili di tipo diverso, fatta eccezione per:

• il vettore di tipo Variant.

Nell'esempio, che segue, inseriremo nel vettore di tipo Variant variabili di tipo differente fra loro:

Public Struct Struttura
  a As Byte
  i As Integer
  s As Short
End Struct
 

Public Sub Main()

 Dim vnt As New Variant[]
 Dim st As String = "testo qualsiasi"
 Dim b As Byte = 99
 Dim sh As Short = 999
 Dim i As Integer = 99999
 Dim stt1 as new Struttura
 Dim stt2 as new Struttura

 With stt1
   .a = 10
   .i = 100000
   .s = 1000
 End With
 
' Inseriamo nel vettore di tipo 'Variant' variabili di tipo differente fra loro:
 With vnt
   .Add(stt1)
   .Add(b)
   .Add(sh)
   .Add(i)
   .Add(st)
 End With

 stt2 = vnt[0]

 Print stt2.a
 Print stt2.i
 Print stt2.s
 Print vnt[1]
 Print vnt[2]
 Print vnt[3]
 Print vnt[4]
 
End

• il vettore di tipo Object, esempio:

Public Struct Prova
  a As Byte
  b As Short
End Struct

Private v As Struct Prova


Public Sub Main()

 Dim a As New Byte[4]
 Dim p As Pointer
 Dim t As Stream
 Dim b As Byte
 Dim ob As New Object[]

 With v
   .a = 99
   .b = 999
 End With
 ob.Add(v)
 Print ob[0].a
 Print ob[0].b
 Print

 a = [1, 2, 3, 4]
 ob.Add(a)
 Print ob[1][0]
 Print ob[1][1]
 Print ob[1][2]
 Print ob[1][3]
 Print

 b = 4
 p = VarPtr(b)
 t = Memory p For Read
 ob.Add(t)
 Read #ob[2], b
 Print b
 Print

End

Una eccezione all'uso del vettore di tipo Object è data dai Puntatori, i quali non consentono che siano assegnati a un elemento di un vettore di tipo Oggetto nella modalità vista appena sopra.
Questo ostacolo, però può essere aggirato come segue:

Public Sub Main()

 Dim b As Byte
 Dim p As Pointer
 Dim o As Object
 Dim ob As New Object[]

 b = 99
 p = VarPtr(b)
 o = [p]
 ob.Add(o)
 Print Val("&" & Pointer@(ob[0][0]))

End