Ottenere un file WAV da un file Midi con la funzione esterna ''gst parse launch()'' del API di GStreamer

E' possibile ottenere un file audio formato WAV da un file Midi mediante una linea di pipeline gestita dalla funzione "gst parse launch()" del API di GStreamer.
E' necessario avere installa nel proprio sistema la libreria condivisa: "libgstreamer-1.0.so.0.2410.0 ".

Mostriamo un esempio pratico:

Library "libgstreamer-1.0:0.2410.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean

' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, position As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()
 
 Dim midi As Pointer
 Dim volume As Float
 Dim durata, l As Long
 Dim tm As Date

 gst_init(0, 0)
  
 midi = gst_parse_launch("filesrc location=/percorso/del/file.mid ! decodebin ! audioconvert ! audioresample ! volume volume=7.0 ! wavenc ! filesink location =/tmp/file.wav", 0)
       
' Avviamo la riproduzione del file Midi per la creazione del file audio WAV:
 gst_element_set_state(midi, GST_STATE_PLAYING)
 
 Repeat
   gst_element_query_duration(midi, GST_FORMAT_TIME, VarPtr(durata))
   Wait 0.01
 Until durata > -1

 tm = Now

 Repeat
   l = DateDiff(tm, Now, gb.Millisecond)
   Write "\r\e[0mDurata: " & Time(0, 0, 0, durata / 1000000) & "      Pos. \e[31m" & Time(0, 0, 0, l)
   Wait 0.001
 Until l >= durata / 1000000

 gst_object_unref(midi)
 Print "\nCreazione del file audio WAV terminata."
      
End

Uso dei plugin specifici di GStreamer per il Midi

Si potrà anche far uso dei plugin specifici di GStreamer per il Midi, che sono:

• midiparse
• fluiddec

In tal caso la stringa della pipeline dei plugin del codice, sopra esposto, sarà la seguente:

midi = gst_parse_launch("filesrc location=/percorso/del/file.mid ! midiparse ! fluiddec ! audioconvert ! audioresample ! volume volume=7.0 ! wavenc ! filesink location =/tmp/file.wav", 0)

Riferimenti

• http://docs.gstreamer.com/display/GstSDK/gst-launch
• http://gstreamer.freedesktop.org/
• http://gstreamer.com/