Copie di variabili array

Per fare una o più copie di una variabile vettoriale, sono possibili alcune modalità.

Con assegnazione diretta fra due variabili array oppure con l'uso del Metodo ".Copy()" del vettore

A seconda della modalità adottata si avrà una situazione diversa.

La copia di un array può avvenire:

• per assegnazione diretta di una variabile vettoriale ad un'altra variabile vettoriale.

Si può fare una copia di un array, assegnando la variabile array ad un'altra variabile array del medesimo tipo di dati:

array_2 = array_1

In questo caso la variabile vettoriale array_2 punta al medesimo indirizzo di memoria della variabile array_1. Hanno nome identificatore diverso, ma puntano alla medesima area di memoria della Struttura CARRAY definita nei sorgenti Gambas, e più precisamente nel file header "gbx_c_array.h".
Ciò significa che, avendo le due variabili array il medesimo indirizzo, qualunque variazione apportata ai dati contenuti da una delle due variabili, o apportata anche agli elementi di una qualsiasi delle due variabili, si rifletterà anche sui dati e/o sugli elementi contenuti nell'altra variabile.

• per attribuzione mediante il Metodo ".Copy()" proprio delle variabili vettoriali:

array_2 = array_1.Copy()

In questo caso la variabile vettoriale array_2 punta ad un indirizzo di memoria diverso da quello dela variabile array_1. Pertanto, le due varibili vettoriali risultano essere indipendenti: le modifiche apportate ai valori o agli elementi di una variabile non incideranno, non avranno effetto anche sull'altra.

Mostriamo quanto sopra esposto con un semplice esempio pratico:

Public Sub Main()
 
 Dim bb, cc As Byte[]

 Print "Effettuiamo la prova con l'assegnazione diretta di un array ad un altro: "
   
 bb = [11, 22, 33, 44]
       
' Assegnamo una variabile array ad un'altra:
 cc = bb
  
' Vediamo l'indirizzo di memoria di ciascuna variabile vettoriale:
 Print Object.Address(bb), Object.Address(cc)
  
' Vediamo quanti elementi posseggono entrambe le variabili:
 Print bb.Count, cc.Count
   
' Incrementiamo il numero di elementi della variabile "bb":
 bb.Push(55)
   
' Vediamo ora quanti elementi posseggono entrambe le variabili:
 Print bb.Count, cc.Count
   
' Incrementiamo il numero di elementi della variabile "cc":
 cc.Push(66)
  
' Vediamo ora quanti elementi posseggono entrambe le variabili:
 Print bb.Count, cc.Count
 cc.Clear
   
 Print "---------------------------"
   
 Print "\nEffettuiamo ora la prova con il metodo '.Copy()': "
   
 bb = [11, 22, 33, 44]
   
' Effettuiamo una copia della variabile "bb" mediante il suo metodo ".Copy()":
 cc = bb.Copy(0, bb.Count)
   
' Vediamo l'indirizzo di memoria di ciascuna variabile vettoriale:
 Print Object.Address(bb), Object.Address(cc)
   
' Vediamo quanti elementi posseggono entrambe le variabili:
 Print bb.Count, cc.Count
   
' Incrementiamo il numero di elementi della variabile "bb":
 bb.Push(55)
   
' Vediamo ora quanti elementi posseggono entrambe le variabili:
 Print bb.Count, cc.Count, " !!!"
   
' Incrementiamo il numero di elementi della variabile "cc":
 cc.Push(66)
   
' Vediamo ora quanti elementi posseggono entrambe le variabili:
 Print bb.Count, cc.Count
   
End

Uso della risorsa Memory Stream

L'assegnazione fra due vettori può avvenire anche mediante la risorsa Memory Stream scrivendo i valori-byte del primo vettore nell'area di memoria appartenente al secondo vettore, destinata a immagazzinare i valori-byte, puntata dalla Proprietà ".Data" di tale vettore.

Mostriamo un semplice esempio:

Public Sub Main()

 Dim bb1 As Byte[] = [11, 22, 33, 44, 55, 66, 77, 88]
 Dim bb2 As New Byte[bb1.Count]
 Dim st As Stream
 
 st = Memory bb2.Data For Write 
 
 bb1.Write(st, 0, bb1.Count)
 
 st.Close
 
 Print bb2[6]

End

Uso della funzione esterna "memcpy()"

La funzione esterna, dichiarata nel file header "/usr/include/string.h ", copia n byte di un'area di memoria, puntata da un Puntatore, in un'altra area di memoria di destinazione, anch'essa puntata da una variabile di tipo Puntatore.

Nel caso di specie utilizzeremo la Proprietà ".Data" di entrambe le variabili vettoriali, quella sorgernte e quella di destinazione dei dati, da passare alla predetta funzione esterna "strcpy()".

Vediamo un semplice esempio:

Library "libc:6"

' void *memcpy (void *__restrict __dest, const void *__restrict __src, size_t __n)
' Copy N bytes of SRC to DEST.
Private Extern memcpy(__dest As Pointer, __src As Pointer, __n As Long) As Pointer


Public Sub Main()
 
 Dim aa, bb As Byte[]
 Dim b As Byte

 bb = [1, 2, 3, 4, 5, 6]
 aa = New Byte[bb.Count]
  
 memcpy(aa.Data, bb.Data, bb.Count)
   
' Vediamo in console il risultato leggendo nella variabile vettoriale "aa":
 For Each b In aa
   Print b
 Next
 
End