Estrarre i dati dagli oggetti presenti sulle schede di una TabStrip

Per estrarre i dati contenuti dagli Oggetti presenti sulle schede di una TabStrip, si potrà seguire in grandi linee il codice esemplificativo che segue.

Poniamo come esempio un Form, sul quale inseriamo un Button ed una TabStrip formato da 3 schede. Ciascuna scheda conterrà una TextLabel ed una TextArea. Alla Proprietà ".Text" di tali TextLabel e TextArea sarà assegnato un valore stringa.

Lo scopo dell'intero codice è di leggere i dati stringa presenti nella Proprietà ".Text" delle TextLabel e TextArea presente in ciascuna scheda della TabStrip.

Public Sub Form_Open()  
 
 Dim b As Byte  
 Dim tl As TextLabel  
 Dim ta As TextArea  
 
' Attribuisce 3 schede alla "TabStrip":
 TabStrip1.Count = 3
 
 For b = 0 To TabStrip1.Count - 1  
' Individua la scheda sulla quale si va ad operare:
   TabStrip1.Index = b
' Crea una "TextLabel" nella scheda attualmente considerata:
   With tl = New TextLabel(TabStrip1)  
     .X = 10  
     .Y = 10  
     .W = 100  
     .H = 50  
     .Text = "tl_" & CStr(b)  
   End With  
' Crea una "TextArea" nella scheda attualmente considerata:
   With ta = New TextArea(TabStrip1)  
     .X = 10
     .Y = 60
     .W = 100
     .H = 50
     .Text = "ta_" & CStr(b)  
   End With
 Next

' Imposta la scheda di indice 0 (ossia la prima) come attiva:
 TabStrip1.Index = 0  

End
 

Public Sub Button1_Click()  
 
 Dim ob As Object  
 Dim b As Byte  

' Prende in considerazione il numero totale delle schede presenti nella "TabStrip":
 For b = 0 To TabStrip1.Count - 1  
' Per "ogni" Oggetto in qualità di "Figlio" presente nella corrente scheda....
   For Each ob In TabStrip1[b].Children  
' ...legge il contenuto della Proprietà ".Text" (...precedentemente assegnato come esempio):
     Print ob.Text  
   Next  
   Print  
 Next  

End